Izpis podatkov iz podatkovne baze

Izpis podatkov iz podatkovne baze Microsoft Access ali SQL je uporabna zadeva. Med drugim jih lahko uporabljamo za izpis podatkov na spletnih straneh, pri manjših aplikacijah in še kje.

Preden se lotimo programiranja potrebujemo podatkovno bazo. V našem primeru uporabljamo Microsoft Access podatkovne baze, lahko pa uporabimo tudi SQL ali kakšne druge podatkovne baze.

Sledi še ASP programiranje, v katerem najprej določimo spremenljivke, sledijo povezave in izpis podatkov skozi zanko.

Koda ASP:
' Določimo spremenljivke
Dim cnnPovezava  ' ADO povezava
Dim rstPovezava  ' ADO povpraševanje
Dim strDBPath  ' pot do naše Access podatkovne baze (*.mdb)

' MapPath nam ustvari pot fizično pot do naše podatkovne baze
' Lahko pa vpišemo tudi celotno pot (C:\mapa\...)
strDBPath = Server.MapPath("pomagalnik.mdb")

' CUstvarimo ADO povezavo do naše podatkovne baze
Set cnnPovezava = Server.CreateObject("ADODB.Connection")

' Povezava do podatkovne baze Access
cnnPovezava.Open "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strDBPath & ";"

' Če bi uporabili SQL pšodatkovno bazo bi rabili
'cnnPovezava.Open "Provider=SQLOLEDB;Data Source=10.2.2.133;" _
'& "Initial Catalog=samples;User Id=Pomagalnik;Password=geslo;" _
'& "Connect Timeout=15;Network Library=dbmssocn;"

' Opravimo povpraševanje. podatki se avtomatsko shranijo v našo spremenljivko
' Za besedo FROM navedemo našo tabelo v podatkovni bazi
Set rstPovezava = cnnPovezava.Execute("SELECT * FROM RSS")

' Prikaz podatkov v tabeli. Imamo zanko, ki gre skozi vse podatke in jih izpiše enega za drugim
' Izpis se konča, ko dobimo EOF - konec vnosa
' V polja, kjer je ID, naslov, datum in vsebina dodamo svoja imena
%>
<table border="1">
<%
Do While Not rstPovezava.EOF
%>
<tr>
<td><%= rstPovezava.Fields("ID").Value %></td>
<td><%= rstPovezava.Fields("naslov").Value %></td>
<td><%= rstPovezava.Fields("datum").Value %></td>
<td><%= rstPovezava.Fields("vsebina").Value %></td>
</tr>
<%
rstPovezava.MoveNext
Loop
%>
</table>
<%
' Zapremo naše povezave in se znebimo podatkov
rstPovezava.Close
Set rstPovezava = Nothing
cnnPovezava.Close
Set cnnPovezava = Nothing
%>

Primer izpisa podatkov iz podatkovne baze

Komentiraj


*